home *** CD-ROM | disk | FTP | other *** search
/ PD Collection CD 1 / PD Collection CD 1.iso / textual / tex / files / !tex / mfinputs / symbol / mf
Encoding:
Text File  |  1988-02-26  |  42.2 KB  |  1,037 lines
  1. % This is SYMBOL.MF in text format, as of Mar 31, 1986.
  2. % This file defines the symbols of a \TeX\ math symbol font.
  3. % Character codes \0000--\00100 and \0133--\0177 are generated.
  4.  
  5. % (Improvements to the author's original characters were worked out in 1982
  6. % by Ronald F. Whitney and other members of
  7. % the American Mathematical Society.)
  8.  
  9. % Italic corrections have not been computed for most of these characters,
  10. % since they are generally not slanted.
  11.  
  12. minus=oct"000"; cdot=oct"001"; diamond=oct"005";
  13. plus_minus=oct"006"; o_plus=oct"010"; o_times=oct"012";
  14. eqv=oct"021"; leq=oct"024"; geq=oct"025";
  15. subset=oct"032"; superset=oct"033";
  16. left_arrow=oct"040"; right_arrow=oct"041";
  17. up_arrow=oct"042"; down_arrow=oct"043"; double_arrow=oct"044";
  18. infty=oct"061"; elt=oct"062";
  19. for_all=oct"070"; there_exists=oct"071"; false_that=oct"072";
  20. cup=oct"133"; cap=oct"134"; meet=oct"136"; join=oct"137";
  21. left_brace=oct"146"; right_brace=oct"147"; vertical=oct"152";
  22. backslash=oct"156"; integral=oct"163";
  23.  
  24. input sym;  % symbols common to other fonts
  25.  
  26. cmchar "Times operator";
  27. beginarithchar(oct"002"); pickup rule.nib;
  28. x1=good.x(1/sqrt2)[.5w,rt u]; y1=good.y(1/sqrt2)[math_axis,bot h];
  29. x2=x3=w-x1; x4=x1; .5[y1,y2]=.5[y3,y4]=math_axis; y2=y4;
  30. draw z1--z2; draw z3--z4;  % diagonals
  31. labels(1,2,3,4); endchar;
  32.  
  33. cmchar "Asterisk at the axis";
  34. beginchar(oct"003",9u#,v_center(x_height#));
  35. adjust_fit(0,0);
  36. numeric ast_flare; ast_flare=hround .7[thin_join,stem];
  37. x0=.5w; y0=h-.5x_height;
  38. for d=-150 step 60 until 150: z[d]=z0+.5dir d xscaled 7.5u yscaled x_height;
  39.  numeric theta; theta=angle(z[d]-z0);
  40.  fill z0+.5(0,-thin_join)rotated theta
  41.   ---z[d]+.5(-ast_flare,-ast_flare)rotated theta
  42.   ..z[d]..z[d]+.5(-ast_flare,ast_flare)rotated theta
  43.   ---z0+.5(0,thin_join)rotated theta--cycle; endfor  % diagonal at angle |d|
  44. labels(0,[-150],[-90],[-30],30,90,150); endchar;
  45.  
  46. cmchar "Elementary division operator";
  47. beginarithchar(oct"004"); pickup rule.nib;
  48. x3-.5dot_size=hround(.5w-.5dot_size); w:=r:=2x3;
  49. y3+.5dot_size=vround(math_axis+math_spread[.5x_height,.6x_height]+.5dot_size);
  50. lft x1=hround u-eps; x2=w-x1; y1=y2=math_axis;
  51. draw z1--z2;  % bar
  52. pos3(dot_size,0); pos4(dot_size,90); z3=z4;
  53. pos5(dot_size,0); pos6(dot_size,90); z5=z6; x5=x3; .5[y3,y5]=math_axis;
  54. dot(3,4); dot(5,6);  % dots
  55. penlabels(1,2,3,4,5,6); endchar;
  56.  
  57. cmchar "Minus-or-plus sign";
  58. beginarithchar(oct"007"); pickup rule.nib;
  59. numeric shiftup; shiftup=-vround 1.5u;
  60. x1=x2=.5w; lft x3=lft=x5=hround u-eps; x4=x6=w-x3;
  61. .5[y1,y2]=y3=y4=math_axis+shiftup; top y1=h+shiftup; y5=y6=y1;
  62. draw z1--z2;  % stem
  63. draw z3--z4;  % plus bar
  64. draw z5--z6;  % minus bar
  65. labels(1,2,3,4,5,6); endchar;
  66.  
  67. cmchar "Circle-minus operator";
  68. beginarithchar(oct"011"); pickup light_rule.nib; autorounded;
  69. lft x6=hround u; x2=w-x6; y2=math_axis; top y8=h;
  70. circle_points; draw_circle;  % circle
  71. draw z2--z6;  % bar
  72. labels(1,2,3,4,5,6,7,8); endchar;
  73.  
  74. cmchar "Circle-divide operator";
  75. beginarithchar(oct"013"); pickup light_rule.nib; autorounded;
  76. lft x6=hround u; x2=w-x6; y2=math_axis; top y8=h;
  77. circle_points; draw_circle;  % circle
  78. draw z1--z5;  % diagonal
  79. labels(1,2,3,4,5,6,7,8); endchar;
  80.  
  81. cmchar "Circle-dot operator";
  82. beginarithchar(oct"014"); pickup light_rule.nib; autorounded;
  83. lft x6=hround u; x2=w-x6; y2=math_axis; top y8=h;
  84. circle_points; draw_circle;  % circle
  85. fill fullcircle scaled(1.3dot_size+eps) shifted(.5[z4,z8]);  % dot
  86. labels(1,2,3,4,5,6,7,8); endchar;
  87.  
  88. cmchar "Circle for copyright, etc.";
  89. beginchar(oct"015",18u#,asc_height#,desc_depth#); autorounded;
  90. adjust_fit(if monospace:-3u#,-3u# else: 0,0 fi); pickup rule.nib;
  91. lft x6=hround u; x2=w-x6; top y8=h+o; bot y4=-d-o;
  92. circle_points; draw_circle;  % circle
  93. labels(1,2,3,4,5,6,7,8); endchar;
  94.  
  95. cmchar "Circle operator";
  96. beginchar(oct"016",9u#,v_center(7u#));
  97. adjust_fit(0,0); pickup rule.nib; autorounded;
  98. lft x6=hround u; x2=w-x6; top y8=h; y2=math_axis;
  99. circle_points; draw_circle;  % circle
  100. labels(1,2,3,4,5,6,7,8); endchar;
  101.  
  102. cmchar "Bullet";
  103. beginchar(oct"017",9u#,v_center(7u#));
  104. adjust_fit(0,0); pickup rule.nib; autorounded;
  105. lft x6=hround u; x2=w-x6; top y8=h; y2=math_axis; circle_points;
  106. filldraw z8{right}...z1{z2-z8}...z2{down}...z3{z4-z2}...z4{left}
  107.   ...z5{z6-z4}...z6{up}...z7{z8-z6}...cycle;  % circle and interior
  108. labels(1,2,3,4,5,6,7,8); endchar;
  109.  
  110. cmchar "Hardy's asymptotic equivalence sign";
  111. compute_spread(.45x_height#,.55x_height#);
  112. beginchar(oct"020",14u#,v_center(2spread#+rule_thickness#));
  113. adjust_fit(0,0); pickup rule.nib; autorounded;
  114. lft x1=hround u-eps; x3=x1; x2=x4=w-x1; x5=x6=.5w;
  115. y1=y2=good.y h; y3=y4; .5[y1,y3]=.5[y5,y6]=math_axis;
  116. y5=good.y .3[y1,y3];
  117. draw z1{x5-x1,2(y5-y1)}...z5{right}...z2{x2-x5,2(y2-y5)};  % upper bar
  118. draw z3{x6-x3,2(y6-y3)}...z6{right}...z4{x4-x6,2(y4-y6)};  % lower bar
  119. labels(1,2,3,4); endchar;
  120.  
  121. cmchar "Subset or equal to sign";
  122. compute_spread(.45x_height#,.55x_height#);
  123. spread#':=spread#; spread':=spread; % the spread of `$=$'
  124. compute_spread(5/4x_height#,3/2x_height#);
  125. beginchar(oct"022",14u#,v_center(spread#'+spread#+rule_thickness#));
  126. adjust_fit(0,0); pickup rule.nib; autorounded;
  127. lft x2=hround 1.5u-eps; x1=x3=w-x2;
  128. y1-y3=spread; y2=.5[y1,y3]; top y1=h;
  129. x4=x5=.5w; y4=y1; y5=y3;
  130. draw z1---z4...z2{down}...z5---z3;  % arc and bars
  131. x8=x1; lft x9=x2; y8=y9; y3-y9=spread'; draw z8--z9;  % lower bar
  132. labels(1,2,3,4,5,8,9); endchar;
  133.  
  134. cmchar "Superset or equal to sign";
  135. compute_spread(.45x_height#,.55x_height#);
  136. spread#':=spread#; spread':=spread; % the spread of `$=$'
  137. compute_spread(5/4x_height#,3/2x_height#);
  138. beginchar(oct"023",14u#,v_center(spread#'+spread#+rule_thickness#));
  139. adjust_fit(0,0); pickup rule.nib; autorounded;
  140. lft x1=hround 1.5u-eps; x2=w-x1; x3=x1;
  141. y1-y3=spread; y2=.5[y1,y3]; top y1=h;
  142. x4=x5=.5w; y4=y1; y5=y3;
  143. draw z1---z4...z2{down}...z5---z3;  % arc and bars
  144. x8=x1; rt x9=x2; y8=y9; y3-y9=spread'; draw z8--z9;  % lower bar
  145. labels(1,2,3,4,5,8,9); endchar;
  146.  
  147. cmchar "Precedes or equals sign";
  148. compute_spread(.45x_height#,.55x_height#);
  149. spread#':=spread#; spread':=spread; % the spread of `$=$'
  150. compute_spread(5/4x_height#,3/2x_height#);
  151. beginchar(oct"026",14u#,v_center(spread#'+spread#+rule_thickness#));
  152. adjust_fit(0,0); pickup rule.nib; autorounded;
  153. lft x2=hround 1.5u-eps; x1=x3=w-x2;
  154. y1-y3=spread; y2=.5[y1,y3]; top y1=h;
  155. draw z1{-u,-spread}...{left}z2;  % upper diagonal
  156. draw z3{-u,spread}...{left}z2;  % lower diagonal
  157. x8=x1; x9=x2; y8=y9; y3-y9=spread'; draw z8--z9;  % bar
  158. labels(1,2,3,8,9); endchar;
  159.  
  160. cmchar "Follows or equals sign";
  161. compute_spread(.45x_height#,.55x_height#);
  162. spread#':=spread#; spread':=spread; % the spread of `$=$'
  163. compute_spread(5/4x_height#,3/2x_height#);
  164. beginchar(oct"027",14u#,v_center(spread#'+spread#+rule_thickness#));
  165. adjust_fit(0,0); pickup rule.nib; autorounded;
  166. lft x1=hround 1.5u-eps; x2=w-x1; x3=x1;
  167. y1-y3=spread; y2=.5[y1,y3]; top y1=h;
  168. draw z1{u,-spread}...{right}z2;  % upper diagonal
  169. draw z3{u,spread}...{right}z2;  % lower diagonal
  170. x8=x1; x9=x2; y8=y9; y3-y9=spread'; draw z8--z9;  % bar
  171. labels(1,2,3,8,9); endchar;
  172.  
  173. cmchar "Similarity sign";
  174. compute_spread(.45x_height#,.55x_height#);
  175. beginchar(oct"030",14u#,v_center(spread#+rule_thickness#));
  176. adjust_fit(0,0);
  177. pickup pencircle xscaled .7rule_thickness yscaled 1.4rule_thickness;
  178. if vair#>.8curve#: pickup rule.nib; autorounded; fi % monoline
  179. lft x1=hround u; x2=4u; x3=w-x2; x4=w-x1;
  180. bot y1=bot y3=-d; top y2=top y4=h;
  181. draw z1{up}...z2{right}..{right}z3...{up}z4;  % stroke
  182. labels(1,2,3,4); endchar;
  183.  
  184. cmchar "Approximate equality sign";
  185. compute_spread(.45x_height#,.55x_height#);
  186. spread#':=spread#; spread':=spread; % the spread of `$=$'
  187. compute_spread(.54x_height#,.66x_height#);
  188. beginchar(oct"031",14u#,v_center(spread#'+spread#+rule_thickness#));
  189. adjust_fit(0,0);
  190. pickup pencircle xscaled .7rule_thickness yscaled 1.4rule_thickness;
  191. if vair#>.8curve#: pickup rule.nib; autorounded; fi % monoline
  192. lft x1=hround u; x2=4u; x3=w-x2; x4=w-x1;
  193. y1=y3; top y2=top y4=h; top y2-bot y1=spread';
  194. draw z1{up}...z2{right}..{right}z3...{up}z4;  % upper stroke
  195. z1-z5=z2-z6=z3-z7=z4-z8=(0,spread);
  196. draw z5{up}...z6{right}..{right}z7...{up}z8;  % lower stroke
  197. labels(1,2,3,4,5,6,7,8); endchar;
  198.  
  199. cmchar "Much less sign";
  200. compute_spread(5/4x_height#,3/2x_height#);
  201. beginchar(oct"034",18u#,v_center(spread#+rule_thickness#));
  202. adjust_fit(if monospace:-u#,-u# else: 0,0 fi); pickup rule.nib;
  203. lft x2=hround u-epsilon; x1=x3=hround 12.5u-x2;
  204. y1-y3=ceiling 1.1spread; y2=.5[y1,y3]=math_axis;
  205. draw z1--z2--z3;  % left diagonals
  206. z4-z1=z5-z2=z6-z3; x4=w-x2; y4=y1;
  207. draw z4--z5--z6;  % right diagonals
  208. labels(1,2,3,4,5,6); endchar;
  209.  
  210. cmchar "Much greater sign";
  211. compute_spread(5/4x_height#,3/2x_height#);
  212. beginchar(oct"035",18u#,v_center(spread#+rule_thickness#));
  213. adjust_fit(if monospace:-u#,-u# else: 0,0 fi); pickup rule.nib;
  214. lft x1=hround u-epsilon; x2=hround 12.5u-x1; x3=x1;
  215. y1-y3=ceiling 1.1spread; y2=.5[y1,y3]=math_axis;
  216. draw z1--z2--z3;  % left diagonals
  217. z4-z1=z5-z2=z6-z3; x4=w-x2; y4=y1;
  218. draw z4--z5--z6;  % right diagonals
  219. labels(1,2,3,4,5,6); endchar;
  220.  
  221. cmchar "Precedes sign";
  222. compute_spread(5/4x_height#,3/2x_height#);
  223. beginchar(oct"036",14u#,v_center(spread#+rule_thickness#));
  224. adjust_fit(0,0); pickup rule.nib; autorounded;
  225. lft x2=hround 1.5u-epsilon; x1=x3=w-x2;
  226. y1-y3=spread; y2=.5[y1,y3]; top y1=h;
  227. draw z1{-u,-spread}...{left}z2;  % upper diagonal
  228. draw z3{-u,spread}...{left}z2;  % lower diagonal
  229. labels(1,2,3); endchar;
  230.  
  231. cmchar "Follows sign";
  232. compute_spread(5/4x_height#,3/2x_height#);
  233. beginchar(oct"037",14u#,v_center(spread#+rule_thickness#));
  234. adjust_fit(0,0); pickup rule.nib; autorounded;
  235. lft x1=hround 1.5u-epsilon; x2=w-x1; x3=x1;
  236. y1-y3=spread; y2=.5[y1,y3]; top y1=h;
  237. draw z1{u,-spread}...{right}z2;  % upper diagonal
  238. draw z3{u,spread}...{right}z2;  % lower diagonal
  239. labels(1,2,3); endchar;
  240.  
  241. cmchar "Northeast arrow";
  242. beginchar(oct"045",18u#,asc_height#,asc_depth#);
  243. adjust_fit(0,0); pickup crisp.nib;
  244. x1-.5rule_thickness=hround u; rt x0=hround(w-u);
  245. y1-.5rule_thickness=-d; top y0=h;
  246. numeric theta,delta; theta=angle(z0-z1); delta=3u++.24asc_height;
  247. if abs(theta-45)<2.5: theta:=45; y1:=y0+x1-x0; fi % near-45$^\circ$ angle
  248. pos1(rule_thickness,90+theta); pos2(rule_thickness,90+theta);
  249. pos3(bar,theta); pos4(bar,theta);
  250. y3=y0; x4=x0; x0-x3=y0-y4=delta+eps;
  251. pos5(bar,-90); z5l=z0; pos6(bar,-180); z6l=z0;
  252. z9=.381966[.5[z3,z4],z0];
  253. numeric t; path p; p=z4l{z9-z4}..z6r;
  254. t=xpart(p intersectiontimes (z1l--(z1l+2(z0-z1)))); z2l=point t of p;
  255. filldraw z0..{z4-z9}z4r--subpath (0,t) of\\(z4l{z9-z4}..z6r)
  256.  --z2l---z1l..z1r---z2r--subpath (t,0) of\\(z3l{z9-z3}..z5r)
  257.  --z3r{z9-z3}..z0 & cycle;  % arrowhead and stem
  258. penlabels(0,1,2,3,4,5,6,9); endchar;
  259.  
  260. cmchar "Southeast arrow";
  261. beginchar(oct"046",18u#,asc_height#,asc_depth#);
  262. adjust_fit(0,0); pickup crisp.nib;
  263. x1-.5rule_thickness=hround u; rt x0=hround(w-u);
  264. y1+.5rule_thickness=h; bot y0=-d;
  265. numeric theta,delta; theta=angle(z0-z1); delta=3u++.24asc_height;
  266. if abs(theta+45)<2.5: theta:=-45; y1:=y0+x0-x1; fi % near-45$^\circ$ angle
  267. pos1(rule_thickness,90+theta); pos2(rule_thickness,90+theta);
  268. pos3(bar,theta); pos4(bar,theta);
  269. x3=x0; y4=y0; y3-y0=x0-x4=delta+eps;
  270. pos5(bar,180); z5l=z0; pos6(bar,90); z6l=z0;
  271. z9=.381966[.5[z3,z4],z0];
  272. numeric t; path p; p=z4l{z9-z4}..z6r;
  273. t=xpart(p intersectiontimes (z1l--(z1l+2(z0-z1)))); z2l=point t of p;
  274. filldraw z0..{z4-z9}z4r
  275.  --subpath (0,t) of\\(z4l{z9-z4}..z6r)
  276.  --z2l---z1l..z1r---z2r
  277.  --subpath (t,0) of\\(z3l{z9-z3}..z5r)
  278.  --z3r{z9-z3}..z0 & cycle;  % arrowhead and stem
  279. penlabels(0,1,2,3,4,5,6,9); endchar;
  280.  
  281. cmchar "Similar or equal sign";
  282. compute_spread(.45x_height#,.55x_height#);
  283. beginchar(oct"047",14u#,v_center(2spread#+rule_thickness#));
  284. adjust_fit(0,0);
  285. pickup pencircle xscaled .7rule_thickness yscaled 1.4rule_thickness;
  286. if vair#>.8curve#: pickup rule.nib; autorounded; fi % monoline
  287. lft x1=hround u; x2=4u; x3=w-x2; x4=w-x1;
  288. bot y1=bot y3=floor math_axis; top y2=top y4=h;
  289. draw z1{up}...z2{right}..{right}z3...{up}z4;  % stroke
  290. pickup rule.nib; lft x5=hround u-eps; x6=w-x5; y5=y6=math_axis-spread;
  291. draw z5--z6;  % bar
  292. labels(1,2,3,4,5,6); endchar;
  293.  
  294. cmchar "Double leftward arrow";
  295. compute_spread(.45x_height#,.55x_height#);
  296. beginchar(oct"050",18u#,v_center(spread#+rule_thickness#));
  297. adjust_fit(0,0); pickup rule.nib;
  298. lft x7=hround u-eps; x8=x7; x1=x2=w-x7;
  299. y1=y7; y2=y8; y1-y2=spread; .5[y1,y2]=math_axis;
  300. draw z1--z7; draw z2--z8;  % bars
  301. pickup crisp.nib; lft x0=hround u-eps; y0=good.y math_axis;
  302. pos3(rule_thickness,0); pos4(rule_thickness,0);
  303. y3-y1=y2-y4=.24asc_height+eps; x3=x4=x0+6u+eps;
  304. pos5(rule_thickness,angle(z4-z0)); z5l=z0;
  305. pos6(rule_thickness,angle(z3-z0)); z6l=z0;
  306. z9=.381966[.5[z3,z4],z0];
  307. erase filldraw z0..{z3-z9}z3--(0,y3)
  308.  --(0,y4)--z4{z9-z4}..z0 & cycle;  % erase excess
  309. numeric t; path p; p=z4r{z9-z4}..z6r;
  310. t=xpart(p intersectiontimes((0,y0)--(w,y0)));
  311. filldraw z0..{z4-z9}z4l--subpath (0,t) of\\(z4r{z9-z4}..z6r)
  312.  --subpath (t,0) of\\(z3r{z9-z3}..z5r)--z3l{z9-z3}..z0 & cycle;  % arrowhead
  313. penlabels(0,1,2,3,4,5,6,7,8,9); endchar;
  314.  
  315. cmchar "Double rightward arrow";
  316. compute_spread(.45x_height#,.55x_height#);
  317. beginchar(oct"051",18u#,v_center(spread#+rule_thickness#));
  318. adjust_fit(0,0); pickup rule.nib;
  319. lft x1=hround u-eps; x2=x1; x7=x8=w-x1;
  320. y1=y7; y2=y8; y1-y2=spread; .5[y1,y2]=math_axis;
  321. draw z1--z7; draw z2--z8;  % bars
  322. pickup crisp.nib; rt x0=hround(w-u)+eps; y0=good.y math_axis;
  323. pos3(rule_thickness,0); pos4(rule_thickness,0);
  324. y3-y1=y2-y4=.24asc_height+eps; x3=x4=x0-6u-eps;
  325. pos5(rule_thickness,angle(z4-z0)); z5l=z0;
  326. pos6(rule_thickness,angle(z3-z0)); z6l=z0;
  327. z9=.381966[.5[z3,z4],z0];
  328. erase filldraw z0..{z3-z9}z3--(w,y3)
  329.  --(w,y4)--z4{z9-z4}..z0 & cycle;  % erase excess
  330. numeric t; path p; p=z4l{z9-z4}..z6r;
  331. t=xpart(p intersectiontimes((0,y0)--(w,y0)));
  332. filldraw z0..{z4-z9}z4r--subpath (0,t) of\\(z4l{z9-z4}..z6r)
  333.  --subpath (t,0) of\\(z3l{z9-z3}..z5r)--z3r{z9-z3}..z0 & cycle;  % arrowhead
  334. penlabels(0,1,2,3,4,5,6,7,8,9); endchar;
  335.  
  336. cmchar "Double upward arrow";
  337. beginchar(oct"052",11u#,asc_height#,asc_depth#);
  338. adjust_fit(0,0); pickup rule.nib;
  339. compute_spread(.45x_height#,.55x_height#);
  340. bot y1=bot y2=-d-eps; top y7=h; y8=y7;
  341. x1=x7; x2=x8; x1-x2=spread; .5[x1,x2]=crisp.lft hround(crisp.rt .5w);
  342. draw z1--z7; draw z2--z8;  % bars
  343. pickup crisp.nib; top y0=h+eps; x0=good.x .5w;
  344. pos3(rule_thickness,90); pos4(rule_thickness,90);
  345. x2-x3=x4-x1=3u+eps; y3=y4=y0-.48asc_height-eps;
  346. pos5(rule_thickness,angle(z4-z0)); z5l=z0;
  347. pos6(rule_thickness,angle(z3-z0)); z6l=z0;
  348. z9=.381966[.5[z3,z4],z0];
  349. erase filldraw z0..{z3-z9}z3--(x3,h)
  350.  --(x4,h)--z4{z9-z4}..z0 & cycle;  % erase excess
  351. numeric t; path p; p=z4l{z9-z4}..z6r;
  352. t=xpart(p intersectiontimes((x0,-d)--(x0,h)));
  353. filldraw z0..{z4-z9}z4r--subpath (0,t) of\\(z4l{z9-z4}..z6r)
  354.  --subpath (t,0) of\\(z3l{z9-z3}..z5r)--z3r{z9-z3}..z0 & cycle;  % arrowhead
  355. penlabels(0,1,2,3,4,5,6,7,8,9); endchar;
  356.  
  357. cmchar "Double downward arrow";
  358. beginchar(oct"053",11u#,asc_height#,asc_depth#);
  359. adjust_fit(0,0); pickup rule.nib;
  360. compute_spread(.45x_height#,.55x_height#);
  361. top y1=top y2=h+eps; bot y7=-d; y8=y7;
  362. x1=x7; x2=x8; x1-x2=spread; .5[x1,x2]=crisp.lft hround(crisp.rt .5w);
  363. draw z1--z7; draw z2--z8;  % bars
  364. pickup crisp.nib; bot y0=-d-eps; x0=good.x .5w;
  365. pos3(rule_thickness,90); pos4(rule_thickness,90);
  366. x2-x3=x4-x1=3u+eps; y3=y4=y0+.48asc_height-eps;
  367. pos5(rule_thickness,angle(z4-z0)); z5l=z0;
  368. pos6(rule_thickness,angle(z3-z0)); z6l=z0;
  369. z9=.381966[.5[z3,z4],z0];
  370. erase filldraw z0..{z3-z9}z3--(x3,-d)
  371.  --(x4,-d)--z4{z9-z4}..z0 & cycle;  % erase excess
  372. numeric t; path p; p=z4r{z9-z4}..z6r;
  373. t=xpart(p intersectiontimes((x0,-d)--(x0,h)));
  374. filldraw z0..{z4-z9}z4l--subpath (0,t) of\\(z4r{z9-z4}..z6r)
  375.  --subpath (t,0) of\\(z3r{z9-z3}..z5r)--z3l{z9-z3}..z0 & cycle;  % arrowhead
  376. penlabels(0,1,2,3,4,5,6,7,8,9); endchar;
  377.  
  378. cmchar "Double left-and-right arrow";
  379. compute_spread(.45x_height#,.55x_height#);
  380. beginchar(oct"054",18u#,v_center(spread#+rule_thickness#));
  381. adjust_fit(if monospace: -u#,-u# else: 0,0 fi); pickup rule.nib;
  382. lft x7=hround u-eps; x8=x7; x1=x2=w-x7;
  383. y1=y7; y2=y8; y1-y2=spread; .5[y1,y2]=math_axis;
  384. draw z1--z7; draw z2--z8;  % bars
  385. pickup crisp.nib; lft x0=hround u-o; y0=good.y math_axis;
  386. pos3(rule_thickness,0); pos4(rule_thickness,0);
  387. y3-y1=y2-y4=.24asc_height+eps; x3=x4=x0+5u+eps;
  388. pos5(rule_thickness,angle(z4-z0)); z5l=z0;
  389. pos6(rule_thickness,angle(z3-z0)); z6l=z0;
  390. z9=.381966[.5[z3,z4],z0];
  391. erase filldraw z0..{z3-z9}z3--(0,y3)
  392.  --(0,y4)--z4{z9-z4}..z0 & cycle;  % erase excess at left
  393. numeric t; path p; p=z4r{z9-z4}..z6r;
  394. t=xpart(p intersectiontimes((0,y0)--(w,y0)));
  395. filldraw z0..{z4-z9}z4l--subpath (0,t) of\\(z4r{z9-z4}..z6r)
  396.  --subpath (t,0) of\\(z3r{z9-z3}..z5r)
  397.  --z3l{z9-z3}..z0 & cycle;  % left arrowhead
  398. rt x10=hround(w-u)+o; y10=good.y math_axis;
  399. pos13(rule_thickness,0); pos14(rule_thickness,0);
  400. y13=y3; y14=y4; x13=x14=x10-5u-eps;
  401. pos15(rule_thickness,angle(z14-z10)); z15l=z10;
  402. pos16(rule_thickness,angle(z13-z10)); z16l=z10;
  403. z19=.381966[.5[z13,z14],z10];
  404. erase filldraw z10..{z13-z19}z13--(w,y13)
  405.  --(w,y14)--z14{z19-z14}..z10 & cycle;  % erase excess at right
  406. numeric t; path p; p=z14l{z19-z14}..z16r;
  407. t=xpart(p intersectiontimes((0,y10)--(w,y10)));
  408. filldraw z10..{z14-z19}z14r--subpath (0,t) of\\(z14l{z19-z14}..z16r)
  409.  --subpath (t,0) of\\(z13l{z19-z13}..z15r)
  410.  --z13r{z19-z13}..z10 & cycle; % right arrowhead
  411. penlabels(0,1,2,3,4,5,6,7,8,9,10,13,14,15,16,19); endchar;
  412.  
  413. cmchar "Northwest arrow";
  414. beginchar(oct"055",18u#,asc_height#,asc_depth#);
  415. adjust_fit(0,0); pickup crisp.nib;
  416. x1+.5rule_thickness=hround(w-u); lft x0=hround u;
  417. y1-.5rule_thickness=-d; top y0=h;
  418. numeric theta,delta; theta=angle(z1-z0); delta=3u++.24asc_height;
  419. if abs(theta+45)<2.5: theta:=-45; y1:=y0+x0-x1; fi % near-45$^\circ$ angle
  420. pos1(rule_thickness,-90+theta); pos2(rule_thickness,-90+theta);
  421. pos3(bar,-180+theta); pos4(bar,-180+theta);
  422. x3=x0; y4=y0; x4-x0=y0-y3=delta+eps;
  423. pos5(bar,0); z5l=z0; pos6(bar,-90); z6l=z0;
  424. z9=.381966[.5[z3,z4],z0];
  425. numeric t; path p; p=z4l{z9-z4}..z6r;
  426. t=xpart(p intersectiontimes (z1l--(z1l+2(z0-z1)))); z2l=point t of p;
  427. filldraw z0..{z4-z9}z4r--subpath (0,t) of\\(z4l{z9-z4}..z6r)
  428.  --z2l---z1l..z1r---z2r--subpath (t,0) of\\(z3l{z9-z3}..z5r)
  429.  --z3r{z9-z3}..z0 & cycle;  % arrowhead and stem
  430. penlabels(0,1,2,3,4,5,6,9); endchar;
  431.  
  432. cmchar "Southwest arrow";
  433. beginchar(oct"056",18u#,asc_height#,asc_depth#);
  434. adjust_fit(0,0); pickup crisp.nib;
  435. x1+.5rule_thickness=hround(w-u); lft x0=hround u;
  436. y1+.5rule_thickness=h; bot y0=-d;
  437. numeric theta,delta; theta=angle(z1-z0); delta=3u++.24asc_height;
  438. if abs(theta-45)<2.5: theta:=45; y1:=y0+x1-x0; fi % near-45$^\circ$ angle
  439. pos1(rule_thickness,-90+theta); pos2(rule_thickness,-90+theta);
  440. pos3(bar,-180+theta); pos4(bar,-180+theta);
  441. y3=y0; x4=x0; x3-x0=y4-y0=delta+eps;
  442. pos5(bar,90); z5l=z0; pos6(bar,0); z6l=z0;
  443. z9=.381966[.5[z3,z4],z0];
  444. numeric t; path p; p=z4l{z9-z4}..z6r;
  445. t=xpart(p intersectiontimes (z1l--(z1l+2(z0-z1)))); z2l=point t of p;
  446. filldraw z0..{z4-z9}z4r
  447.  --subpath (0,t) of\\(z4l{z9-z4}..z6r)
  448.  --z2l---z1l..z1r---z2r
  449.  --subpath (t,0) of\\(z3l{z9-z3}..z5r)
  450.  --z3r{z9-z3}..z0 & cycle;  % arrowhead and stem
  451. penlabels(0,1,2,3,4,5,6,9); endchar;
  452.  
  453. cmchar "Proportionality sign";
  454. beginchar(oct"057",16.5u#,x_height#,0);
  455. italcorr x_height#*slant-.5u#;
  456. adjust_fit(0,-2.5u#); pickup fine.nib;
  457. numeric theta,phi; phi=angle(3u,h); theta=angle(5u,-h);
  458. pos1(vair,180); pos2(.5[vair,stem],90+.5theta); pos3(stem,90+theta);
  459. pos4(stem,90+theta); pos5(.5[vair,stem],90+.5theta);
  460. pos6(vair,180); pos7(.2[vair,stem],270+.5phi);
  461. pos8(.3[vair,stem],270+phi); pos9(.2[vair,stem],270+.5phi);
  462. lft x1r=w-rt x6l=hround u; x2=x9=.4[x1,x8]; x5=x7=.6[x8,x6];
  463. if monospace: x2l:=x2r; x5r:=x5l; x7r:=x7l; x9l:=x9r; fi
  464. y1=y6=.5h; top y2r=top y7l=h+oo; bot y5l=bot y9r=-oo;
  465. x8=.5[x3,x4]=.5w; y8=.5[y3,y4]=.5h;
  466. y3-y4=h/3; z3-z4=whatever*dir theta;
  467. filldraw stroke z1e{up}...z2e{right}...z3e---z4e...z5e{right}...z6e{up}
  468.  ...z7e{left}...{-dir phi}z8e...{left}z9e...z1e{up}; % `infinity' bowls
  469. erase fill (w-3.5u,h+o)--(w,h+o)
  470.  --(w,-o)--(w-3.5u,-o)--cycle; % erase excess
  471. penlabels(1,2,3,4,5,6,7,8,9); endchar;
  472.  
  473. cmchar "Prime symbol (intended as superscript only)";
  474. beginchar(oct"060",3u#+max(1.75u#,curve#+2(curve#-stem#)),
  475.  .8asc_height#,0);
  476. adjust_fit(0,0); pickup fine.nib;
  477. numeric light_stem,heavy_stem;
  478. light_stem=hround .5[vair,stem]; heavy_stem=hround(bold+2dw);
  479. x1+.5heavy_stem=hround(w-.25u); y1+.5heavy_stem=h;
  480. x2-.5light_stem=hround .5u; y2=1/12asc_height;
  481. numeric theta; theta=angle(z1-z2)-90;
  482. pos1(heavy_stem,theta); pos2(light_stem,theta);
  483. filldraw circ_stroke z1e--z2e;  % diagonal
  484. penlabels(1,2); endchar;
  485.  
  486. cmchar "Ownership sign";
  487. compute_spread(5/4x_height#,3/2x_height#);
  488. beginchar(oct"063",12u#,v_center(spread#+rule_thickness#));
  489. adjust_fit(0,0); pickup rule.nib; autorounded;
  490. lft x1=hround 1.5u-eps; x1=x3=x6=w-x2;
  491. y1-y3=spread; y2=y6=.5[y1,y3]=math_axis;
  492. x4=x5=.5w-u; y4=y1; y5=y3;
  493. draw z1---z4...z2{down}...z5---z3;  % arc and bars
  494. draw z2--z6;  % middle bar
  495. labels(1,2,3,4,5,6); endchar;
  496.  
  497. cmchar "Large triangle";
  498. beginchar(oct"064",16u#,asc_height#,desc_depth#);
  499. adjust_fit(0,0); pickup rule.nib;
  500. bot y1=0; y2=y1; top y3=h+o;
  501. .5[x1,x2]=x3=good.x .5w; w:=r:=2x3; lft x1=hround(.5w-u*sqrt48);
  502. draw z1--z2--z3--cycle;  % stroke
  503. labels(1,2,3); endchar;
  504.  
  505. cmchar "Large inverted triangle";
  506. beginchar(oct"065",16u#,asc_height#,desc_depth#);
  507. adjust_fit(0,0); pickup rule.nib;
  508. top y1=h-d; y2=y1; bot y3=-d-o;
  509. .5[x1,x2]=x3=good.x .5w; w:=r:=2x3; lft x1=hround(.5w-u*sqrt48);
  510. draw z1--z2--z3--cycle;  % stroke
  511. labels(1,2,3); endchar;
  512.  
  513. cmchar "Zero-width slash to negate a relation";
  514. beginchar(oct"066",14u#,asc_height#,asc_depth#);
  515. adjust_fit(0,0); pickup rule.nib;
  516. rt x5=hround(w-2.5u)-eps; lft x6=hround 2.5u+eps;
  517. top y5=h+o; .5[y5,y6]=math_axis;
  518. draw z5--z6;  % diagonal
  519. labels(1,2); zero_width; endchar;
  520.  
  521. cmchar "Maps-to relation";
  522. compute_spread(.45x_height#,.55x_height#);
  523. beginchar(oct"067",14u#,v_center(spread#+rule_thickness#));
  524. % this character should be followed immediately by minus or rightarrow
  525. adjust_fit(0,0); pickup rule.nib;
  526. lft x1=hround u; x2=x1+.5u; x3=x4=x1;
  527. y1=y2=math_axis; y1-y3=y4-y1=.24asc_height+eps;
  528. draw z3--z4;  % stem
  529. draw z1--z2;  % bar stub
  530. labels(1,2,3,4); zero_width; endchar;
  531.  
  532. cmchar "Empty set symbol";
  533. beginchar(oct"073",9u#,body_height#,body_height#-asc_height#);
  534. adjust_fit(0,0);
  535. penpos1(vair,90); penpos3(vair,-90); penpos2(stem,180); penpos4(stem,0);
  536. if not monospace: interim superness:=sqrt(more_super*hein_super); fi
  537. x2r=hround max(.7u,1.45u-.5stem);
  538. x4r=w-x2r; x1=x3=.5w; y1r=asc_height+o; y3r=-o;
  539. y2=y4=.5asc_height-vair_corr; y2l:=y4l:=.52asc_height;
  540. penstroke pulled_arc.e(1,2) & pulled_arc.e(2,3)
  541.  & pulled_arc.e(3,4) & pulled_arc.e(4,1) & cycle;  % bowl
  542. pickup rule.nib; lft x6=hround 2u-eps; x5=w-x6; top y5=h+o; bot y6=-d-o;
  543. draw z5--z6;  % diagonal
  544. penlabels(1,2,3,4,5,6); endchar;
  545.  
  546. cmchar "Uppercase Fraktur R";
  547. beginchar(oct"074",13u#,asc_height#,0);
  548. adjust_fit(0,0); pickup fine.nib;
  549. pos1(hair,0); pos2(vair,90); pos3(1/6[hair,stem],190);
  550. pos4(1/4[hair,stem],210); pos5(1/8[hair,stem],190);
  551. pos6(vair,90); pos7(cap_stem,0); pos8(cap_stem,0);
  552. pos9(vair,-90); pos10(hair,-135); pos11(hair,-135);
  553. pos12(vair,135); pos13(vair,135);
  554. lft x1l=lft x5r=hround u; x2=.4[x1,x3]; rt x3l=hround 3.5u; x4=.6[x3,x5];
  555. x6=3u; lft x7=hround(6u-.5cap_stem); x8=x7;
  556. x9=3.5u; x10=5/3u; x11=4/3u; x12=u; x13=2u;
  557. y1=.47h; bot y2l=vround.35h; y3=1/3[y2,y6]; y5=3/4[y2,y6]; y4=.6[y3,y5];
  558. top y6r=h+oo; y7=.64h; y8=.57y7; bot y9r=-o;
  559. y10=1/6y7; y12=1/5y7; y13=1/4y7;
  560. z11-z10=whatever*(z13-z12) rotated 90;
  561. filldraw stroke z1e{down}...z2e{right}...z3e{up}..z4e..z5e{up}
  562.  ...pulled_arc.e(6,7)..pulled_arc.e(8,9)
  563.  ...z10e---z11e;  % flourish and left stem
  564. filldraw stroke z12e--z13e;  % cross
  565. pos20(cap_bar,180); pos21(cap_bar,90);
  566. x20=x7; y20=.75h; rt x21=hround(w-3.5u+.5cap_stem); top y21r=h+o;
  567. filldraw stroke z20e{up}...{right}z21e;  % top of bowl
  568. rt x22r=hround(w-.1u); y22r=good.y .64h;
  569. numeric theta; theta=angle(z21r-z22r);
  570. pos22(cap_stem,theta-90); pos23(cap_bar,theta); z22l=z23l;
  571. path p; p=z20{up}...(z21--(w,y21));
  572. z=p intersectionpoint(z22l--z22l+(h,0) rotated theta);
  573. filldraw z--z21r--z22r--z22l--cycle;  % diagonal of bowl
  574. pos24(cap_bar,90); pos25(cap_bar,90); x24=w-4u; x25=x7;
  575. y24=y25; top y24r=vround(.52h+.5cap_bar);
  576. filldraw stroke z23e{dir(theta+90)}...z24e---z25e;  % bottom of bowl
  577. pos26(cap_stem,0); pos27(cap_stem,0); pos28(cap_stem,0);
  578. x26=x24; x27=x26+.25u; x28l=w-2.5u; y26=y24r; y27=1/3y26; bot y28=-o;
  579. filldraw stroke z26e--z27e...{right}z28e;  % lower diagonal
  580. pos29(cap_bar,0); pos30(cap_bar,-30); z29l=z28l;
  581. x30r=good.x(w-.5u); y30r=good.y .09h;
  582. erase filldraw z29r--z28r--z30r--cycle;  % erase excess
  583. filldraw stroke z29e--z30e;  % serif of lower diagonal
  584. %% \begingroup\thinmuskip=3mu
  585. penlabels(1,2,3,4,5,6,7,8,9,10,11,12,13,20,21,22,23,24,25,26,27,28,29,30);
  586. %% \endgroup
  587. endchar;
  588.  
  589. cmchar "Uppercase Fraktur I";
  590. beginchar(oct"075",13u#,asc_height#,0);
  591. adjust_fit(0,0); pickup fine.nib;
  592. pos1(vair,270); pos2(cap_hair,180); pos3(vair,90);
  593. pos4(cap_stem,0); pos5(vair,90); pos6(cap_hair,180);
  594. x1=5u; lft x2r=hround u; x3=.5[x2,x4l]; x4r=x5-.75u;
  595. x5=.5[x4l,x6l]; rt x6l=hround(w-.5u);
  596. top y1l=vround.5h; y2=.5[y1,y3]; top y3r=h+oo;
  597. y4=.2[y5,y3]; y6=.3[y5,y3]; bot y5l=ceiling(1/6[x_height,h]);
  598. filldraw stroke z1e{left}...z2e{up}...z3e{right}
  599.  ..z4e..z5e{right}...{up}z6e;  % upper stroke
  600. pos7(vair,90); pos8(cap_stem,0); pos9(cap_stem,0);
  601. lft x7=hround u; z7r=z8l; x9=.5w+u; y8=good.y .25h; bot y9=-oo;
  602. filldraw z8l---z8r..{right}z9r+(0,eps)
  603.  --z9r---z9l..{left}z7l--cycle;  % lower left stroke
  604. pos10(cap_stem,0); pos11(cap_stem,0); pos12(vair,-90); pos13(cap_hair,-180);
  605. x10=w-2.5u; x11r=x12-u; x12=x5; x13=x6;
  606. y10=1/3y12; y11=3/4y12; top y12l=x_height; y13=4/5y12;
  607. filldraw z9l+(0,eps){right}...{up}z10l
  608.  --z10r{down}...z9r---z9l--cycle;  % lower link
  609. filldraw stroke z10e{up}...z11e{up}
  610.  ...z12e{right}...{down}z13e;  % lower right stroke
  611. penlabels(1,2,3,4,5,6,7,8,9,10,11,12,13); endchar;
  612.  
  613. cmchar "Lattice top";
  614. beginchar(oct"076",14u#,asc_height#,0);
  615. adjust_fit(0,0); pickup rule.nib;
  616. x1=x2=good.x .5w; w:=r:=2x1; lft x3=hround u; x4=r-x3;
  617. bot y1=0; y2-y1=x4-x3;
  618. if top y2>h: y2:=bot h; fi
  619. y3=y4=y2;
  620. draw z1--z2;  % stem
  621. draw z3--z4;  % bar
  622. labels(1,2,3,4); endchar;
  623.  
  624. cmchar "Perpendicular sign or lattice bottom";
  625. beginchar(oct"077",14u#,asc_height#,0);
  626. adjust_fit(0,0); pickup rule.nib;
  627. x1=x2=good.x .5w; w:=r:=2x1; lft x3=hround u; x4=r-x3;
  628. bot y1=0; y2-y1=x4-x3;
  629. if top y2>h: y2:=bot h; fi
  630. y3=y4=y1;
  631. draw z1--z2;  % stem
  632. draw z3--z4;  % bar
  633. labels(1,2,3,4); endchar;
  634.  
  635. cmchar "Hebrew letter aleph";
  636. beginchar(oct"100",11u#,asc_height#,0);
  637. adjust_fit(0,0); pickup fine.nib;
  638. pos1(cap_stem,75); pos2(cap_stem,90); pos3(cap_stem,90); pos4(cap_stem,75);
  639. lft x1l=hround u-eps; x2=2.5u=w-x3; rt x4r=hround(w-u)+eps;
  640. top y1r=h; bot y4l=0; z2=whatever[z1l,z4r]; z3=whatever[z1l,z4r];
  641. filldraw z1r{4(x1l-x1r),y1l-y1r}...{down}z1l...z2l
  642.  ---z3l...{down}z4l{4(x4r-x4l),y4r-y4l}...{up}z4r...z3r
  643.  ---z2r...{up}cycle; % long diagonal
  644. pos5(cap_stem,75); pos6(cap_stem,90); pos7(cap_stem,75);
  645. lft x5l=hround(w-4u)-eps; x6=.5[x5,x7]; x7=x4;
  646. y5=y1; bot y7l=x_height-o; z6=whatever[z5l,z7r];
  647. filldraw z5r{4(x5l-x5r),y5l-y5r}...{down}z5l
  648.  ...z6l{z7r-z5l}...{down}z7l{4(x7r-x7l),y7r-y7l}...{up}z7r
  649.  ...z6r{z5l-z7l}...{up}cycle; % short diagonal
  650. pos8(cap_hair,0); pos9(cap_hair,0); z8=z6; x9=x8-.75u; z9=whatever[z2,z3];
  651. filldraw stroke z8e{down}..{down}z9e;  % right stem
  652. pos10(cap_hair,-30); pos11(stem,0);
  653. pos12(cap_curve,0); pos13(cap_curve,0); pos14(vair,90);
  654. lft x11l=hround 1.5u; x10=x12=.4[x11,.5w]; z10=whatever[z2,z3];
  655. lft x13l=hround u; z13l=z14l; y11=.5y10; y12=.2[y14r,y11]; bot y13=0;
  656. filldraw stroke z10e{2(x11-x10),y11-y10}
  657.  ...z11e{down}..{down}z12e; % left stem
  658. filldraw z12r{down}...z13r---z13l--z14r{right}...{up}z12l--cycle; % flourish
  659. penlabels(1,2,3,4,5,6,7,8,9,10,11,12,13,14); endchar;
  660.  
  661. cmchar "Multiset union sign";
  662. beginchar(oct"135",12u#,.8asc_height#,0); autorounded;
  663. adjust_fit(if monospace:-.5u#,-.5u# else: 0,0 fi); pickup rule.nib;
  664. lft x1=hround u; x2=x1; x3=w-x3; x4=x5=w-x1;
  665. y1=good.y h+o; bot y3=-o; y2=y4=2/3[y1,y3]; y5=y1;
  666. draw z1---z2...z3...z4---z5;  % stems and cup
  667. y8=y9=.47[y1,y3]; x8=w-x9=x1+2rule_thickness+eps;
  668. x6=x7=x3; .5[y6,y7]=y8; y7-y6=x9-x8;
  669. draw z8--z9; draw z6--z7;  % enclosed plus sign
  670. labels(1,2,3,4,5,6,7,8,9); endchar;
  671.  
  672. cmchar "Left turnstile";
  673. beginchar(oct"140",11u#,asc_height#,0);
  674. adjust_fit(0,0); pickup rule.nib;
  675. .5[y1,y2]=y3=y4; x1=x2=x3;
  676. lft x3=hround u; x4=w-x3; top y1=h; bot y2=0;
  677. draw z1--z2;  % stem
  678. draw z3--z4;  % bar
  679. labels(1,2,3,4); endchar;
  680.  
  681. cmchar "Right turnstile";
  682. beginchar(oct"141",11u#,asc_height#,0);
  683. adjust_fit(0,0); pickup rule.nib;
  684. .5[y1,y2]=y3=y4; x1=x2=x4;
  685. lft x3=hround u; x4=w-x3; top y1=h; bot y2=0;
  686. draw z1--z2;  % stem
  687. draw z3--z4;  % bar
  688. labels(1,2,3,4); endchar;
  689.  
  690. cmchar "Left floor bracket";
  691. beginchar(oct"142",8u#,body_height#,paren_depth#);
  692. adjust_fit(0,0); pickup rule.nib;
  693. x1=x2=good.x 3.5u; x3=x1+3.75u+eps;
  694. top y1=h; .5[y1,y2]=math_axis; y3=y2;
  695. draw z1--z2--z3;  % stem and bar
  696. labels(1,2,3); endchar;
  697.  
  698. cmchar "Right floor bracket";
  699. beginchar(oct"143",8u#,body_height#,paren_depth#);
  700. adjust_fit(0,0); pickup rule.nib;
  701. x1=x2=good.x(w-3.5u); x3=x1-3.75u-eps;
  702. top y1=h; .5[y1,y2]=math_axis; y3=y2;
  703. draw z1--z2--z3;  % stem and bar
  704. labels(1,2,3); endchar;
  705.  
  706. cmchar "Left ceiling bracket";
  707. beginchar(oct"144",8u#,body_height#,paren_depth#);
  708. adjust_fit(0,0); pickup rule.nib;
  709. x1=x2=good.x 3.5u; x3=x1+3.75u+eps;
  710. top y1=h; .5[y1,y2]=math_axis; y3=y1;
  711. draw z3--z1--z2;  % stem and bar
  712. labels(1,2,3); endchar;
  713.  
  714. cmchar "Right ceiling bracket";
  715. beginchar(oct"145",8u#,body_height#,paren_depth#);
  716. adjust_fit(0,0); pickup rule.nib;
  717. x1=x2=good.x(w-3.5u); x3=x1-3.75u-eps;
  718. top y1=h; .5[y1,y2]=math_axis; y3=y1;
  719. draw z3--z1--z2;  % stem and bar
  720. labels(1,2,3); endchar;
  721.  
  722. cmchar "Left angle bracket";
  723. beginchar(oct"150",7u#,body_height#,paren_depth#);
  724. adjust_fit(0,0); pickup rule.nib;
  725. rt x1=hround(w-u)+eps; x1=x3; lft x2=hround 2u-1-eps;
  726. top y1=h+eps; .5[y1,y3]=y2=math_axis;
  727. draw z1--z2--z3;  % diagonals
  728. labels(1,2,3); endchar;
  729.  
  730. cmchar "Right angle bracket";
  731. beginchar(oct"151",7u#,body_height#,paren_depth#);
  732. adjust_fit(0,0); pickup rule.nib;
  733. rt(w-x1)=hround(w-u)+eps; x1=x3; lft(w-x2)=hround 2u-1-eps;
  734. top y1=h+eps; .5[y1,y3]=y2=math_axis;
  735. draw z1--z2--z3;  % diagonals
  736. labels(1,2,3); endchar;
  737.  
  738. cmchar "Double vertical line (norm or cardinality)";
  739. beginchar(oct"153",9u#,body_height#,paren_depth#);
  740. adjust_fit(0,0); pickup rule.nib;
  741. x1=x2; top y1=h; .5[y1,y2]=math_axis;
  742. x3=x4=w-x1; y3=y1; y4=y2;
  743. compute_spread(.45x_height#,.55x_height#); x3-x1=spread;
  744. draw z1--z2; draw z3--z4;  % stems
  745. labels(1,2,3,4); endchar;
  746.  
  747. cmchar "Up-and-down arrow";
  748. beginchar(oct"154",9u#,body_height#,paren_depth#);
  749. adjust_fit(0,0); pickup crisp.nib;
  750. pos1(rule_thickness,0); pos2(rule_thickness,0);
  751. pos3(bar,90); pos4(bar,90);
  752. lft x1l=hround(.5w-.5rule_thickness); y1=.5[-d,h];
  753. x0=x1=x2; bot y0=-d-o; x0-x3=x4-x0=3u+eps;
  754. y3=y4=y0+.24asc_height+eps;
  755. pos5(bar,angle(z4-z0)); z5l=z0; pos6(bar,angle(z3-z0)); z6l=z0;
  756. z9=.381966[.5[z3,z4],z0];
  757. numeric t; path p; p=z4r{z9-z4}..z6r;
  758. t=xpart(p intersectiontimes((x2r,-d)--(x2r,h))); y2=ypart point t of p;
  759. filldraw z0..{z4-z9}z4l--subpath (0,t) of\\(z4r{z9-z4}..z6r)
  760.  --z2r---z1r..z1l---z2l--subpath (t,0) of\\(z3r{z9-z3}..z5r)
  761.  --z3l{z9-z3}..z0 & cycle;  % lower arrowhead and stem
  762. pos11(rule_thickness,0); pos12(rule_thickness,0); z11=z1;
  763. pos13(bar,90); pos14(bar,90);
  764. x10=x11=x12; top y10=h+o; x10-x13=x14-x10=3u+eps;
  765. y13=y14=y10-.24asc_height-eps;
  766. pos15(bar,angle(z14-z10)); z15l=z10; pos16(bar,angle(z13-z10)); z16l=z10;
  767. z19=.381966[.5[z13,z14],z10];
  768. numeric t; path p; p=z14l{z19-z14}..z16r;
  769. t=xpart(p intersectiontimes((x12r,-d)--(x12r,h))); y12=ypart point t of p;
  770. filldraw z10..{z14-z19}z14r--subpath (0,t) of\\(z14l{z19-z14}..z16r)
  771.  --z12r---z11r..z11l---z12l--subpath (t,0) of\\(z13l{z19-z13}..z15r)
  772.  --z13r{z19-z13}..z10 & cycle;  % upper arrowhead and stem
  773. penlabels(0,1,2,3,4,5,6,9,10,11,12,13,14,15,16,19); endchar;
  774.  
  775. cmchar "Double up-and-down arrow";
  776. beginchar(oct"155",11u#,body_height#,paren_depth#);
  777. adjust_fit(0,0); pickup rule.nib;
  778. compute_spread(.45x_height#,.55x_height#);
  779. bot y1=bot y2=-d-eps; top y7=h; y8=y7;
  780. x1=x7; x2=x8; x1-x2=spread; .5[x1,x2]=crisp.lft hround(crisp.rt .5w);
  781. draw z1--z7; draw z2--z8;  % bars
  782. pickup crisp.nib; top y0=h+o; x0=good.x .5w;
  783. pos3(rule_thickness,90); pos4(rule_thickness,90);
  784. x2-x3=x4-x1=3u+eps; y3=y4=y0-.4asc_height-eps;
  785. pos5(rule_thickness,angle(z4-z0)); z5l=z0;
  786. pos6(rule_thickness,angle(z3-z0)); z6l=z0;
  787. z9=.381966[.5[z3,z4],z0];
  788. erase filldraw z0..{z3-z9}z3--(x3,h)
  789.  --(x4,h)--z4{z9-z4}..z0 & cycle;  % erase excess at top
  790. numeric t; path p; p=z4l{z9-z4}..z6r;
  791. t=xpart(p intersectiontimes((x0,-d)--(x0,h)));
  792. filldraw z0..{z4-z9}z4r--subpath (0,t) of\\(z4l{z9-z4}..z6r)
  793.  --subpath (t,0) of\\(z3l{z9-z3}..z5r)
  794.  --z3r{z9-z3}..z0 & cycle;  % top arrowhead
  795. bot y10=-d-o; x10=good.x .5w;
  796. pos13(rule_thickness,90); pos14(rule_thickness,90);
  797. x13=x3; x14=x4; y13=y14=y10+.4asc_height-eps;
  798. pos15(rule_thickness,angle(z14-z10)); z15l=z10;
  799. pos16(rule_thickness,angle(z13-z10)); z16l=z10;
  800. z19=.381966[.5[z13,z14],z10];
  801. erase filldraw z10..{z13-z19}z13--(x13,-d)
  802.  --(x14,-d)--z14{z19-z14}..z10 & cycle;  % erase excess at bottom
  803. numeric t; path p; p=z14r{z19-z14}..z16r;
  804. t=xpart(p intersectiontimes((x10,-d)--(x10,h)));
  805. filldraw z10..{z14-z19}z14l--subpath (0,t) of\\(z14r{z19-z14}..z16r)
  806.  --subpath (t,0) of\\(z13r{z19-z13}..z15r)
  807.  --z13l{z19-z13}..z10 & cycle;  % bottom arrowhead
  808. penlabels(0,1,2,3,4,5,6,7,8,9,13,14,15,16,19); endchar;
  809.  
  810. cmchar "Wreath product";
  811. beginchar(oct"157",5u#,asc_height#,asc_depth#);
  812. adjust_fit(if monospace: u#,u# else: 0,0 fi);
  813. pickup pencircle yscaled .7rule_thickness xscaled 1.4rule_thickness;
  814. if vair#>.8curve#: pickup rule.nib; autorounded; fi % monoline
  815. lft x1=lft x3=hround u; x2=x4=w-x1;
  816. top y1=vround .75[math_axis,h];
  817. .5[y1,y4]=.5[y2,y3]=math_axis; y1-y2=1/4(y1-y4);
  818. draw z1{right}...z2{down}..{down}z3...{right}z4;  % stroke
  819. labels(1,2,3,4); endchar;
  820.  
  821. cmchar "Radical sign";
  822. beginchar(oct"160",15u#,rule_thickness#,
  823.  body_height#+paren_depth#-rule_thickness#);
  824. big_sqrt; endchar;
  825.  
  826. cmchar "Amalgamation symbol or coproduct symbol";
  827. beginchar(oct"161",13u#+width_adj#,cap_height#,0);
  828. italcorr cap_height#*slant-cap_serif_fit#+cap_jut#-2.5u#+min(.5cap_stem#,u#);
  829. adjust_fit(cap_serif_fit#,cap_serif_fit#);
  830. pickup tiny.nib; pos1(cap_stem,0); pos2(cap_stem,0);
  831. pos3(cap_stem,0); pos4(cap_stem,0);
  832. lft x1l=lft x2l=hround max(2u,3u-.5cap_stem); x3=x4=w-x1;
  833. top y1=top y3=h; bot y2=bot y4=0;
  834. filldraw stroke z1e--z2e; % left stem
  835. filldraw stroke z3e--z4e; % right stem
  836. penpos5(cap_bar,90); penpos6(cap_bar,90);
  837. x5=x1; x6=x3; y5=y6; y5l=0;
  838. fill stroke z5e--z6e;  % bar
  839. if serifs: numeric inner_jut;
  840.  if rt x1r+cap_jut+u+2<=lft x3l-cap_jut: inner_jut=cap_jut;
  841.  else: rt x1r+inner_jut+u+2=lft x3l-inner_jut; fi
  842.  dish_serif(1,2,a,1/3,cap_jut,b,1/3,inner_jut);  % upper left serif
  843.  nodish_serif(2,1,c,1/3,cap_jut,d,1/3,eps); % lower left serif
  844.  dish_serif(3,4,e,1/3,inner_jut,f,1/3,cap_jut);  % upper right serif
  845.  nodish_serif(4,3,g,1/3,eps,h,1/3,cap_jut); fi  % lower right serif
  846. math_fit(0,.5ic#); penlabels(1,2,3,4,5,6); endchar;
  847.  
  848. cmchar "Nabla or backwards-difference operator";
  849. beginchar(oct"162",15u#,cap_height#,0);
  850. adjust_fit(0,0);
  851. numeric right_stem,alpha;
  852. right_stem=cap_hair if hefty: -3stem_corr fi;
  853. x1l=w-x4r=.75u; y1=y4=h;
  854. x2-x1=x4-x3; x3l=x2l+apex_corr; y2=y3=-apex_o-apex_oo;
  855. alpha=diag_ratio(2,right_stem,y1-y2,x4r-x1l-apex_corr);
  856. penpos1(alpha*cap_stem,0); penpos2(alpha*cap_stem,0);
  857. penpos3(alpha*right_stem,0); penpos4(alpha*right_stem,0);
  858. fill diag_end(2l,1l,1,1,4r,3r)--diag_end(4r,3r,1,1,2l,1l)--cycle;  % triangle
  859. z0=whatever[z1r,z2r]=whatever[z3l,z4l];
  860. y5=y6=h-cap_vstem; z5=whatever[z1r,z2r]; z6=whatever[z3l,z4l];
  861. if y0>cap_notch_cut: y0:=cap_notch_cut;
  862.  unfill z0+.5right{up}...{z4-z3}z6--z5{z2-z1}
  863.   ...{down}z0+.5left--cycle; % counter
  864. else: unfill z0--z5--z6--cycle; fi  % counter
  865. penlabels(0,1,2,3,4,5,6); endchar;
  866.  
  867. cmchar "Square set union sign (Scott lub)";
  868. beginchar(oct"164",12u#,.8asc_height#,0);
  869. adjust_fit(0,0); pickup rule.nib;
  870. lft x1=hround 1.1u; x2=x1; x4=x5=w-x1;
  871. y1=good.y h+o; bot y2=0; y4=y2; y5=y1;
  872. draw z1---z2---z4---z5;  % stems and bar
  873. labels(1,2,4,5); endchar;
  874.  
  875. cmchar "Square set intersection sign (Scott glb)";
  876. beginchar(oct"165",12u#,.8asc_height#,0);
  877. adjust_fit(0,0); pickup rule.nib;
  878. lft x1=hround 1.1u; x2=x1; x4=x5=w-x1;
  879. y2=good.y h+o; bot y1=0; y4=y2; y5=y1;
  880. draw z1---z2---z4---z5;  % stems and bar
  881. labels(1,2,4,5); endchar;
  882.  
  883. cmchar "Square subset or equal to sign";
  884. compute_spread(.45x_height#,.55x_height#);
  885. spread#':=spread#; spread':=spread; % the spread of `$=$'
  886. compute_spread(5/4x_height#,3/2x_height#);
  887. beginchar(oct"166",14u#,v_center(spread#'+spread#+rule_thickness#));
  888. adjust_fit(0,0); pickup rule.nib;
  889. lft x2=hround(1.5u+oo); x1=x4=hround(w-1.5u)+eps; x3=x2;
  890. y1-y4=spread; y2=y1; y3=y4; top y1=h;
  891. draw z1--z2--z3--z4;  % bars and stem
  892. x8=x1; x9=x2-oo-eps; y8=y9; y4-y9=spread';
  893. draw z8--z9;  % lower bar
  894. labels(1,2,3,4,8,9); endchar;
  895.  
  896. cmchar "Square superset or equal to sign";
  897. compute_spread(.45x_height#,.55x_height#);
  898. spread#':=spread#; spread':=spread; % the spread of `$=$'
  899. compute_spread(5/4x_height#,3/2x_height#);
  900. beginchar(oct"167",14u#,v_center(spread#'+spread#+rule_thickness#));
  901. adjust_fit(0,0); pickup rule.nib;
  902. x1=x4=hround 1.5u-eps; rt x2=hround(w-1.5u-oo); x3=x2;
  903. y1-y4=spread; y2=y1; y3=y4; top y1=h;
  904. draw z1--z2--z3--z4;  % bars and stem
  905. x8=x1; x9=x2+oo+eps; y8=y9; y4-y9=spread';
  906. draw z8--z9;  % lower bar
  907. labels(1,2,3,4,8,9); endchar;
  908.  
  909. cmchar "Section sign";
  910. beginchar(oct"170",6.5u#+max(1.5u#,stem#),asc_height#,desc_depth#);
  911. adjust_fit(0,0); pickup fine.nib;
  912. numeric sstem; sstem=hround .75[hair,stem];
  913. pos0(stem,0); pos1(hair,0); pos2(vair,90); pos3(sstem,180); pos4(vair,270);
  914. pos5'(sstem,0); pos5(sstem,180);
  915. pos6(vair,90); pos7(sstem,0); pos8(vair,-90); pos9(hair,-180); pos10(stem,-180);
  916. top y2r=h+oo; bot y8r=-d-oo; y2-y1=y9-y8=(y2-y8)/8;
  917. y3=.52[y4,y2]; y5=.52[y4,y6]; y7=.52[y6,y8]; y5'=.52[y6,y4];
  918. y2-y4=y4-y6=y6-y8;
  919. rt x1r=hround(w-1.5u); lft x3r=hround 1.25u;
  920. x2=x4=x6=x8=.5w; x5=x7=w-x3; x5'=x3; x9=w-x1;
  921. bulb(2,1,0); bulb(8,9,10);  % bulbs
  922. filldraw stroke z2e{left}...z3e{down}...z4e{3(x5-x3),y5-y3}
  923.  ...z5e{down}...{left}z6e;  % upper stroke
  924. filldraw stroke z4e{left}...z5'e{down}...z6e{3(x7-x5'),y7-y5'}
  925.  ...z7e{down}...{left}z8e;  % upper stroke
  926. penlabels(0,1,2,3,4,5,6,7,8,9,10); endchar;
  927.  
  928. cmchar "Dagger mark";
  929. beginchar(oct"171",8u#,asc_height#,desc_depth#);
  930. adjust_fit(0,0); pickup fine.nib;
  931. pos1(stem,0); pos2(thin_join,0); pos3(stem,0); pos4(hair,0);
  932. pos5(stem,90); pos2'(thin_join,90); pos6(stem,90); z2'=z2;
  933. x1=x2=x3=x4; x1-.5stem=hround(.5w-.5stem); w:=r:=2x1;
  934. x5-.5stem=hround u; x6=w-x5;
  935. y1+.5stem=h+oo; y2=y5=y6; y3=.57y2; bot y4=-d-o;
  936. y5+.5stem=floor(x_height+.5stem);
  937. filldraw circ_stroke z1e{down}..z2e{down}..z3e{down}..z4e;  % stem
  938. filldraw circ_stroke z5e{right}..{right}z2'e;  % left bulb
  939. filldraw circ_stroke z6e{left}..{left}z2'e;  % right bulb
  940. penlabels(1,2,3,4,5,6); endchar;
  941.  
  942. cmchar "Double dagger mark";
  943. beginchar(oct"172",8u#,asc_height#,desc_depth#);
  944. adjust_fit(0,0); pickup fine.nib;
  945. pos1(stem,0); pos2(thin_join,0); pos3(stem,0);
  946. pos4(stem,90); pos2'(thin_join,90); pos5(stem,90); z2'=z2;
  947. x1=x2=x3; x1-.5stem=hround(.5w-.5stem); w:=r:=2x1;
  948. x4-.5stem=hround u; x5=w-x4;
  949. y1+.5stem=h+oo; y2=y4=y5=.5[y1,y3]; y3-.5stem=ceiling(.5[-d,h]);
  950. filldraw circ_stroke z1e{down}..{down}z2e;  % top stem
  951. filldraw circ_stroke z3e{up}..{up}z2e;    % upper middle stem
  952. filldraw circ_stroke z4e{right}..{right}z2'e;  % top left bulb
  953. filldraw circ_stroke z5e{left}..{left}z2'e;  % top right bulb
  954. pos6(stem,0); pos7(thin_join,0); pos8(stem,0);
  955. pos9(stem,90); pos7'(thin_join,90); pos0(stem,90); z7'=z7;
  956. x6=x7=x8=x1; x9=x4; x0=x5;
  957. y6=y3-stem-1; y7=y9=y0=.5[y6,y8]; y8-.5stem=-d-oo;
  958. filldraw circ_stroke z6e{down}..{down}z7e;  % lower middle stem
  959. filldraw circ_stroke z8e{up}..{up}z7e;    % bottom stem
  960. filldraw circ_stroke z9e{right}..{right}z7'e;  % bottom left bulb
  961. filldraw circ_stroke z0e{left}..{left}z7'e;  % bottom right bulb
  962. penlabels(1,2,3,4,5,6,7,8,9,0); endchar;
  963.  
  964. cmchar "Paragraph mark";
  965. beginchar(oct"173",11u#,asc_height#,desc_depth#);
  966. adjust_fit(0,0); pickup rule.nib; autorounded;
  967. top y1=h; bot y6=-d-eps; y4=y7=y9=y1;
  968. y8=y6; y3=y5=good.y .5[y1,y6];
  969. x7-x4=ceiling(rule_thickness+1.25u);
  970. lft x2=hround u; y2=.5[y1,y3]; x4=x5=x6; rt x9=hround(w-.5u);
  971. x7=x8=good.x(x9-1.5u); x1=x3=min(.5w,x4);
  972. filldraw z4..z1{left}...z2{down}...{right}z5--cycle;  % filled bowl
  973. draw z9--z4--z6;  % left stem and upper serif
  974. draw z7--z8;  % right stem
  975. labels(1,2,3,4,5,6,7,8,9); endchar;
  976.  
  977. cmchar "Club suit";
  978. beginchar(oct"174",14u#,asc_height#,2/3desc_depth#);
  979. adjust_fit(0,0); pickup rule.nib; autorounded;
  980. x1=x4=x30=x33=good.x .5w; w:=r:=2x1;
  981. x2=good.x(x1-.5u)-eps; lft x1-rt x10=hround .5pt; lft x12=hround .5u;
  982. x11=.6[x12,x10]; x13=.5[x12,x10]=x5; x32-x31=x1-.5u-x12;
  983. x2+x3=x5+x6=x10+x20=x11+x21=x12+x22=x13+x23=x31+x32=2x1;
  984. top y30=h+o+oo; bot y11=bot y21=-o; top y13=top y23=vround .53h;
  985. y30-y33=y13-y11; y31=y32=y4=.5[y30,y33]; y12=y22=.5[y11,y13];
  986. y1=y10=y20=good.y .1h; bot y5=bot y6=y1+.75; bot y2=bot y3=-d;
  987. filldraw z30{left}...z31{down}...z33{right}...z32{up}...cycle;  % top bowl
  988. filldraw z13{left}...z12{down}...z11{right}...z10{up}...cycle;  % left bowl
  989. filldraw z23{left}...z20{down}...z21{right}...z22{up}...cycle;  % right bowl
  990. filldraw z1{down}...{2(x2-x1),y2-y1}z2--z3{2(x1-x3),y1-y3}
  991.  ...{up}cycle;  % stem
  992. filldraw z4--z5--z6--cycle;  % filling
  993. labels(1,2,3,4,5,6,10,11,12,13,20,21,22,23,30,31,32,33); endchar;
  994.  
  995. cmchar "Diamond suit";
  996. beginchar(oct"175",14u#,asc_height#,2/3desc_depth#);
  997. adjust_fit(0,0); pickup rule.nib; autorounded;
  998. x1=x4=good.x .5w; w:=r:=2x1;
  999. lft x2=hround u; x3=w-x2;
  1000. top y1=h+o+oo; bot y4=-d-o-oo; y2=y3=.5[y1,y4];
  1001. draw z1{x3-x1,1.5(y3-y1)}...z3{1.5(x3-x1),y3-y1};  % upper right diagonal
  1002. draw z1{x2-x1,1.5(y2-y1)}...z2{1.5(x2-x1),y2-y1};  % upper left diagonal
  1003. draw z4{x2-x4,1.5(y2-y4)}...z2{1.5(x2-x4),y2-y4};  % lower left diagonal
  1004. draw z4{x3-x4,1.5(y3-y4)}...z3{1.5(x3-x4),y3-y4};  % lower right diagonal
  1005. labels(1,2,3,4); endchar;
  1006.  
  1007. cmchar "Heart suit";
  1008. beginchar(oct"176",14u#,asc_height#,2/3desc_depth#);
  1009. adjust_fit(0,0); pickup rule.nib; autorounded;
  1010. x1=x5=good.x .5w; w:=r:=2x1;
  1011. lft x7=hround u; x8=4u; x2+x8=x3+x7=x4+x6=w;
  1012. y1=good.y .77h; top y2=h+o; y3=.7h; y4=.2h; bot y5=-o-oo;
  1013. y2=y8; y3=y7; y4=y6; z4=whatever[z3,z5];
  1014. x0=x9=w; y0=1.5h; y9=.6h;
  1015. draw z1{x2-x1,8(y2-y1)}...z2{right}....z3{down}...{z4-z9}z4
  1016.  ...{z5-z0}z5;  % right half bowl
  1017. draw z1{x8-x1,8(y8-y1)}...z8{left}....z7{down}...{(z4-z9)xscaled-1}z6
  1018.  ...{(z5-z0)xscaled-1}z5;  % left half bowl
  1019. labels(0,1,2,3,4,5,6,7,8,9); endchar;
  1020.  
  1021. cmchar "Spade suit";
  1022. beginchar(oct"177",14u#,asc_height#,2/3desc_depth#);
  1023. adjust_fit(0,0); pickup rule.nib; autorounded;
  1024. x1=x10=good.x .5w; w:=r:=2x1;
  1025. x2=good.x(x1-.5u)-eps; lft x1-rt x6=hround .5pt; x5=x6;
  1026. x7=.5[x8,x6]; lft x8=hround u;
  1027. x2+x3=x5+x15=x6+x14=x7+x13=x8+x12=x9+x11=2x10;
  1028. top y10=h+o+oo; y9=y11=.7h; y8=y12=.3h;
  1029. y1=y6=y14=good.y .1h; bot y5=bot y15=y1+.75;
  1030. bot y7=bot y13=-o; bot y2=bot y3=-d; z9=whatever[z8,z10];
  1031. filldraw z10{-w,-3h}...z9{-w,-h}...z8{down}...z7{right}...z6---z5
  1032.  --z15---z14...{right}z13...{up}z12...{-w,h}z11
  1033.  ...{-w,3h}cycle;  % filled bowl
  1034. filldraw z1{down}...{2(x2-x1),y2-y1}z2--z3{2(x1-x3),y1-y3}
  1035.  ...{up}cycle;  % stem
  1036. labels(1,2,3,5,6,10,11,12,13,14,15); endchar;
  1037.